动手编写 mbr 代码

上一篇文章中，我们讲述了关于如何搭建编写操作系统所需的环境。如果你还没有相应的环境，那先动手搭建吧。参见「centos-6+bochs+virtualBox」环境搭建。

这篇文章，我们会自己手动编写 mbr 文件，向屏幕中输出 1 MBR 字符。O(∩_∩)O哈哈~，有没有跃跃欲试的感觉，那让我们开始吧~

创建启动盘

在 bochs 安装目录下，有个 bin/bximage 可执行文件，它是 bochs 提供磁盘工具，可用于创建虚拟磁盘。

到 bochs 目录下，执行如下代码，创建 hd60M.img 启动盘。

// -hd 创建硬盘
// -mode 硬盘类型，有 flat，sparse，growing
// -size 盘的大小，MB
// -q 静默创建
bin/bximage -hd -mode="flat" -size=60 -q hd60M.img

创建成功后，添加如下配置到 bochsrc.disk 文件中，添加到最后一行即可。

ata0-master: type=disk, path="hd60M.img", mode=flat

编写 mbr 代码

新建 mbr.S 文件，其代码如下：

;主引导程序
;------------------------------------------------------------
SECTION MBR vstart=0x7c00
mov ax,cs
mov ds,ax
mov es,ax
mov ss,ax
mov fs,ax
mov sp,0x7c00

; 清屏利用 0x06 号功能,上卷全部行,则可清屏｡
; -----------------------------------------------------------
;INT 0x10 功能号:0x06 功能描述:上卷窗口
;------------------------------------------------------
;输入:
;AH 功能号= 0x06
;AL = 上卷的行数(如果为 0,表示全部)
;BH = 上卷行属性
;(CL,CH) = 窗口左上角的(X,Y)位置
;(DL,DH) = 窗口右下角的(X,Y)位置
;无返回值:
mov ax, 0x600
mov bx, 0x700
mov cx, 0 ; 左上角: (0, 0)
mov dx, 0x184f ; 右下角: (80,25),
; VGA 文本模式中,一行只能容纳 80 个字符,共 25 行｡
; 下标从 0 开始,所以 0x18=24,0x4f=79
int 0x10 ; int 0x10

;;;;;;;;; 下面这三行代码获取光标位置 ;;;;;;;;;
;.get_cursor 获取当前光标位置,在光标位置处打印字符｡
mov ah, 3 ; 输入: 3 号子功能是获取光标位置,需要存入 ah 寄存器
mov bh, 0 ; bh 寄存器存储的是待获取光标的页号

int 0x10 ; 输出: ch=光标开始行,cl=光标结束行
; dh=光标所在行号,dl=光标所在列号

;;;;;;;;; 获取光标位置结束 ;;;;;;;;;;;;;;;;

;;;;;;;;; 打印字符串 ;;;;;;;;;;;
;还是用 10h 中断,不过这次调用 13 号子功能打印字符串
mov ax, message
mov bp, ax ; es:bp 为串首地址,es 此时同 cs 一致,
; 开头时已经为 sreg 初始化

; 光标位置要用到 dx 寄存器中内容,cx 中的光标位置可忽略
mov cx, 5 ; cx 为串长度,不包括结束符 0 的字符个数
mov ax, 0x1301 ;子功能号 13 显示字符及属性,要存入 ah 寄存器,
; al 设置写字符方式 ah=01: 显示字符串,光标跟随移动
mov bx, 0x2 ; bh 存储要显示的页号,此处是第 0 页,
; bl 中是字符属性,属性黑底绿字(bl = 02h)
int 0x10 ; 执行 BIOS 0x10 号中断
;;;;;;;;; 打字字符串结束 ;;;;;;;;;;;;;;;

jmp $ ; 使程序悬停在此

message db "1 MBR"

; $是当前行地址，$$ 是当前 section 起始地址，($ - $$) 计算出前面的偏移，并去除最后 2 字节，将剩余部分填充为 0
times 510-($-$$) db 0

;最后 2 字节，固定为 0x55,0xaa
db 0x55,0xaa

mbr 有如下特性：

• 在磁盘第 1 个扇区。
• 总共 512 字节。
• 结尾固定是 0x55 和 0xaa，占用 2 字节。

注释写的很详细了。我们重点关注下最后两行代码：

; $是当前行地址，$$ 是当前 section 起始地址，($ - $$) 计算出前面的偏移，并去除最后 2 字节，将剩余部分填充为 0
times 510-($-$$) db 0

;最后 2 字节，固定为 0x55,0xaa
db 0x55,0xaa

由于要满足 512 字节大小的要求，因此需要在去除头尾后，将中间剩余部分进行填充，这里填充的是 0。并且，我们可以看到，最后两字节确实是固定写死为 0x55, 0xaa。

使用 nasm 将其编译为机器指令，输出文件为 mbr.bin。

nams -o mbr.bin mbr.S

写入虚拟磁盘

现在代码部分完成了，但 mbr 的代码需要在磁盘特定的位置上。下面我们将其写入到正确的位置，我们将使用 dd 命令来完成。

输入如下命令，将 mbr.bin 中的内容写到之前创建的虚拟磁盘 hd60M.img 中，指定块大小 512 字节，占用 1 块。

// if：输入文件
// of：输出文件
// bs：块大小
// count：块数量
// conv：如何转换文件，notrunc 表示不切断文件
dd if=mbr.bin of=/packages/bochs/hd60M.img bs=512 count=1 conv=notrunc

执行成功后，会显示下图红框中部分：

加载 mbr

输入命令：bin/bochs -f bochsrc.disk，启动 bochs。由于是进入了调试模式，需再次按下 c，即 continue，让其继续执行。之后就可以看到在屏幕上输出了 1 MBR 字符啦。如下图所示：