庄懂的TA笔记（十一）＜Tiling+面板玩法+函数复用+库的用法＞
目录：
一、shader面板玩法 > 增广 : 多种 面板设计玩法：
二、shader参数类型 > 增广 ：认识 多种参数类型 ：
三、增广 ：认识 IVO = (InPut vertex outPut)
四、代码 方法 的 重复使用 == 函数(一段代码的重复使用)：
五、代码 库 的 重复使用 (跨脚本代码的重复使用)：
一、shader面板玩法：
例如：
1、[HideInInspector] 隐藏某参数面板：
//隐藏下列参数面板，记得结尾加or
[HideInInspector] _Other ("隐藏图", 2D)="whitae"{}
2、[NoScaleOffset] 禁用纹理TilingOffset：
3、[Normal] 自动检测是否为法线，如不是会弹出提示 是否 Fix。
4、[HDR] 设置高动态范围色值，例如 灯光颜色，自发光。
5、[Gamma] 用于颜色参数的色彩空间的转换，一半用于色彩空间为Linear的项目；
6、[PowerSlider(value)]对范围参数做Power处理后再传入shader，纠正部分参数调节手感；
7、[Header(Label)] 标签，用于排版；
8、[Space(value)] 空行，用与排版；
9、[Toggle] [Enum] [Keyword] 等 暂时不用知道，自定义Drawer 需要一定C#能力。
二、shader参数类型：
三、认识 IVO = (InPut vertex outPut)：
红色标注为：启用Tiling的缩放功能。
或者：
四、代码 方法 的 重复使用 == 函数(一段代码的重复使用)：
实际上就是吧 传输的命名变量，进行替换，即可。
五、代码 库 的 重复使用 == 库 (跨脚本代码的重复使用)：
1、改后缀：.cginc
2、形式段 + 代码段：
3、库的导入 与 引用：
直接保留应用段即可，因为已经在库中有这段方法了。
注意：
这里在实践过程中，我遇到了，始终找不到库文件的问题，解决方法为，去掉 库文件的前缀文件夹，放在与调用shader同级下的位置。
一旦库文件被调用的shader识别，那么库文件可以任意移动，反之则不行。
（库文件的名称，可以与内部的开头结构不一样<AI说的>）
Shader "AP01/L11/OldSchoolPro" {
Properties {
[Header(Texture)]
_MainTex ("RGB:基础颜色 A:环境遮罩", 2D) = "white" {}
[Normal] _NormTex ("RGB:法线贴图", 2D) = "bump" {}
_SpecTex ("RGB:高光颜色 A:高光次幂", 2D) = "gray" {}
_EmitTex ("RGB:环境贴图", 2d) = "black" {}
_Cubemap ("RGB:环境贴图", cube) = "_Skybox" {}
[Header(Diffuse)]
_MainCol ("基本色", Color) = (0.5, 0.5, 0.5, 1.0)
_EnvDiffInt ("环境漫反射强度", Range(0, 1)) = 0.2
_EnvUpCol ("环境天顶颜色", Color) = (1.0, 1.0, 1.0, 1.0)
_EnvSideCol ("环境水平颜色", Color) = (0.5, 0.5, 0.5, 1.0)
_EnvDownCol ("环境地表颜色", Color) = (0.0, 0.0, 0.0, 0.0)
[Header(Specular)]
[PowerSlider(2)] _SpecPow ("高光次幂", Range(1, 90)) = 30
_EnvSpecInt ("环境镜面反射强度", Range(0, 5)) = 0.2
_FresnelPow ("菲涅尔次幂", Range(0, 5)) = 1
_CubemapMip ("环境球Mip", Range(0, 7)) = 0
[Header(Emission)]
[HideInInspect] _EmitInt ("自发光强度", range(1, 10)) = 1
}
SubShader {
Tags {
"RenderType"="Opaque"
}
Pass {
Name "FORWARD"
Tags {
"LightMode"="ForwardBase"
}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
// 追加投影相关包含文件
#include "AutoLight.cginc"
#include "Lighting.cginc"
#include "../cginc/MyCginc.cginc"
#pragma multi_compile_fwdbase_fullshadows
#pragma target 3.0
// 输入参数
// Texture
uniform sampler2D _MainTex; uniform float4 _MainTex_ST;
uniform sampler2D _NormTex;
uniform sampler2D _SpecTex;
uniform sampler2D _EmitTex;
uniform samplerCUBE _Cubemap;
// Diffuse
uniform float3 _MainCol;
uniform float _EnvDiffInt;
uniform float3 _EnvUpCol;
uniform float3 _EnvSideCol;
uniform float3 _EnvDownCol;
// Specular
uniform float _SpecPow;
uniform float _FresnelPow;
uniform float _EnvSpecInt;
uniform float _CubemapMip;
// Emission
uniform float _EmitInt;
// 输入结构
struct VertexInput {
float4 vertex : POSITION; // 顶点信息 Get✔
float2 uv0 : TEXCOORD0; // UV信息 Get✔
float4 normal : NORMAL; // 法线信息 Get✔
float4 tangent : TANGENT; // 切线信息 Get✔
};
// 输出结构
struct VertexOutput {
float4 pos : SV_POSITION; // 屏幕顶点位置
float2 uv0 : TEXCOORD0; // UV0
float4 posWS : TEXCOORD1; // 世界空间顶点位置
float3 nDirWS : TEXCOORD2; // 世界空间法线方向
float3 tDirWS : TEXCOORD3; // 世界空间切线方向
float3 bDirWS : TEXCOORD4; // 世界空间副切线方向
LIGHTING_COORDS(5,6) // 投影相关
};
// 输入结构>>>顶点Shader>>>输出结构
VertexOutput vert (VertexInput v) {
VertexOutput o = (VertexOutput)0; // 新建输出结构
o.pos = UnityObjectToClipPos( v.vertex ); // 顶点位置 OS>CS
o.uv0 = v.uv0 * _MainTex_ST.xy + _MainTex_ST.zw;// 传递UV
o.posWS = mul(unity_ObjectToWorld, v.vertex); // 顶点位置 OS>WS
o.nDirWS = UnityObjectToWorldNormal(v.normal); // 法线方向 OS>WS
o.tDirWS = normalize(mul(unity_ObjectToWorld, float4(v.tangent.xyz, 0.0)).xyz); // 切线方向 OS>WS
o.bDirWS = normalize(cross(o.nDirWS, o.tDirWS) * v.tangent.w); // 副切线方向
TRANSFER_VERTEX_TO_FRAGMENT(o) // 投影相关
return o; // 返回输出结构
}
// 输出结构>>>像素
float4 frag(VertexOutput i) : COLOR {
// 准备向量
float3 nDirTS = UnpackNormal(tex2D(_NormTex, i.uv0)).rgb;
float3x3 TBN = float3x3(i.tDirWS, i.bDirWS, i.nDirWS);
float3 nDirWS = normalize(mul(nDirTS, TBN));
float3 vDirWS = normalize(_WorldSpaceCameraPos.xyz - i.posWS.xyz);
float3 vrDirWS = reflect(-vDirWS, nDirWS);
float3 lDirWS = _WorldSpaceLightPos0.xyz;
float3 lrDirWS = reflect(-lDirWS, nDirWS);
// 准备点积结果
float ndotl = dot(nDirWS, lDirWS);
float vdotr = dot(vDirWS, lrDirWS);
float vdotn = dot(vDirWS, nDirWS);
// 采样纹理
float4 var_MainTex = tex2D(_MainTex, i.uv0);
float4 var_SpecTex = tex2D(_SpecTex, i.uv0);
float3 var_EmitTex = tex2D(_EmitTex, i.uv0).rgb;
float3 var_Cubemap = texCUBElod(_Cubemap, float4(vrDirWS, lerp(_CubemapMip, 0.0, var_SpecTex.a))).rgb;
// 光照模型(直接光照部分)
float3 baseCol = var_MainTex.rgb * _MainCol;
float lambert = max(0.0, ndotl);
float specCol = var_SpecTex.rgb;
float specPow = lerp(1, _SpecPow, var_SpecTex.a);
float phong = pow(max(0.0, vdotr), specPow);
float shadow = LIGHT_ATTENUATION(i);
float3 dirLighting = (baseCol * lambert + specCol * phong) * _LightColor0 * shadow;
// 光照模型(环境光照部分)
float3 envCol = TriColAmbient(nDirWS, _EnvUpCol, _EnvSideCol, _EnvDownCol);
float fresnel = pow(max(0.0, 1.0 - vdotn), _FresnelPow); // 菲涅尔
float occlusion = var_MainTex.a;
float3 envLighting = (baseCol * envCol * _EnvDiffInt + var_Cubemap * fresnel * _EnvSpecInt * var_SpecTex.a) * occlusion;
// 光照模型(自发光部分)
float3 emission = var_EmitTex * _EmitInt * (sin(_Time.z) * 0.5 + 0.5);
// 返回结果
float3 finalRGB = dirLighting + envLighting + emission;
return float4(finalRGB, 1.0);
}
ENDCG
}
}
FallBack "Diffuse"
}今天的文章庄懂的TA笔记（十一）＜Tiling+面板玩法+函数复用+库的用法 ＞分享到此就结束了，感谢您的阅读。
版权声明：本文内容由互联网用户自发贡献，该文观点仅代表作者本人。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容， 请发送邮件至 举报，一经查实，本站将立刻删除。
如需转载请保留出处：https://bianchenghao.cn/88979.html
